AddOption('--release', action = 'store_true')

env = Environment(CPPPATH = ['.'], CCFLAGS = ['-pthread'], LINKFLAGS = ['-pthread'])

if env['PLATFORM'] == 'darwin':
	env.Append(LIBS = ['boost_system', 'boost_filesystem', 'boost_regex', 'boost_thread', 'boost_program_options', 'mp3lame', 'avformat', 'avcodec', 'soci_core'])
else:
	conf = Configure(env)
	for lib in ['boost_system-mt', 'boost_filesystem-mt', 'boost_regex-mt','boost_thread-mt', 'boost_program_options-mt', 'mp3lame']:
		if not conf.CheckLib(lib):
			Exit(1)
	# scons' CheckLib doesn't seem to find soci_core
	if conf.CheckCXXHeader('soci/soci.h'):
		env.Append(LIBS = ['soci_core'])
	env = conf.Finish()
	env.ParseConfig('pkg-config --cflags --libs libavcodec')
	env.ParseConfig('pkg-config --cflags --libs libavformat')

if GetOption('release'):
	env.Append(CCFLAGS = ['-O2'])
else:
	env.Append(CCFLAGS = ['-Wall', '-g'])

env.ParseConfig('pkg-config --cflags --libs libmpg123')
env.ParseConfig('pkg-config --cflags --libs id3tag')

env.Program('audistd', Glob('*.cpp') + Glob('decoders/*.cpp') + Glob('encoders/*.cpp'))

# vim: syn=python